<?xml version="1.0" encoding="ISO-8859-1"?>

<!-- habilitation.v01.xsl contient tous les templates d'affichage des informations d'une habilitation de CDM-fr -->

<xsl:stylesheet version="1.0"
	xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
	exclude-result-prefixes="xsl xhtml"
	xmlns="http://www.w3.org/1999/xhtml"
	xmlns:xhtml="http://www.w3.org/1999/xhtml">


	<!-- Numéro d'habilitation de la mention lorsqu'il est présent ou Identifiant ROF de la mention ou de la formation hors LMD -->
	<xsl:template name="tHabilitationHabiliID">
		<xsl:value-of select="key('objet',$_oid)/habilitation/habiliId"/>
	</xsl:template>
	
	<xsl:template name="tHabilitationLegalRef">
		<xsl:apply-templates select="key('objet',$_oid)/habilitation/legalRef"/>
	</xsl:template>

	<xsl:template name="tHabilitationHabiliObject">
		<xsl:if test="key('objet',$_oid)/habilitation/habiliObject/refProgram/@ref">
			<ul>
				<xsl:apply-templates select="key('objet',$_oid)/habilitation/habiliObject/refProgram"/>
			</ul>
		</xsl:if>
	</xsl:template>

	<xsl:template name="tHabilitationDiplomaType">
		<xsl:value-of select="key('objet',$_oid)/habilitation/@diplomaType"/>
	</xsl:template>

	<xsl:template name="tHabilitationOrganization">
		<xsl:value-of select="key('objet',$_oid)/habilitation/@Organization"/>
	</xsl:template>

	<!-- Intitulé Mention -->
	<xsl:template name="tHabilitationFieldFieldNameFree">
		<xsl:value-of select="key('objet',$_oid)/habilitation/field/fieldName/free/text"/>
	</xsl:template>
	
	<!-- Finalité (recherche, professionnelle ou les 2 -->
	<xsl:template name="tHabilitationFieldFieldPurpose">
		<xsl:value-of select="key('objet',$_oid)/habilitation/field/@fieldPurpose"/>
	</xsl:template>

	<!-- Domaine -->
	<xsl:template name="tHabilitationFieldFieldPrimaryDomainName">
		<xsl:apply-templates select="key('objet',$_oid)/habilitation/domainName/fixedDomain"/>
	</xsl:template>
	
	<xsl:template match="fixedDomain">
		<xsl:value-of select="."/><xsl:text> </xsl:text>
	</xsl:template>
	
	<xsl:template name="tHabilitationFieldFieldOtherDomainName">
		<xsl:value-of select="key('objet',$idP)/habilitation/field/@otherDomainName"/>
	</xsl:template>
	
	<xsl:template name="tHabilitationFieldFieldFieldTimingInfoRenewalDateDate">
		<xsl:value-of select="key('objet',$idP)/habilitation/field/fieldTimingInfo/renewalDateDate[@blockLang=$_lang or not(@blockLang)]/@date"/>
	</xsl:template>
	
	<xsl:template name="tHabilitationFieldSpeciality">
		<xsl:if test="key('objet',$_oid)/habilitation/field/speciality">
			<ul>
				<xsl:apply-templates select="key('objet',$_oid)/habilitation/field/speciality"/>
			</ul>
		</xsl:if>
	</xsl:template>
	
	<xsl:template match="speciality">
		<li><xsl:value-of select="specialityName/text[@language=$_lang or not(@language)]"/>
			<ul>
				<li><xsl:call-template name="tCommunGestionLibelle"><xsl:with-param name="pIdent" select="'libDateRenouvellement'"/></xsl:call-template>
				<xsl:value-of select="specialityTimingInfo/renewalDateDate/@date"/></li>
				<li><xsl:call-template name="tCommunGestionLibelle"><xsl:with-param name="pIdent" select="'libDureeHabilitation'"/></xsl:call-template>
				<xsl:value-of select="specialityTimingInfo/@duration"/></li>
				<li><xsl:call-template name="tCommunGestionLibelle"><xsl:with-param name="pIdent" select="'libObjectif'"/></xsl:call-template>
				<xsl:value-of select="@specialityPurpose"/></li>
				<li><xsl:call-template name="tCommunGestionLibelle"><xsl:with-param name="pIdent" select="'libCohabilitation'"/></xsl:call-template>
				<xsl:apply-templates select="cohabilitation"/></li>
			</ul>
		</li>
	</xsl:template>

	<!-- Descriptif de la cohabilitation de la formation -->
	<xsl:template match="cohabilitation">
		<xsl:choose>
				<xsl:when test="exists='false'"><xsl:call-template name="tCommunGestionLibelle"><xsl:with-param name="pIdent" select="'libAucuneCohabilitation'"/></xsl:call-template></xsl:when>
				<xsl:when test="exists='true'">
					<ul>
						<li><xsl:call-template name="tCommunGestionLibelle"><xsl:with-param name="pIdent" select="'libCodeRNE'"/></xsl:call-template> (<xsl:value-of select="listOfOrgUnit/@cohabilitationRole"/>)<xsl:text> </xsl:text> 
							<xsl:choose>
								<xsl:when test="count(listOfOrgUnit/habOrgUnit/refOrgUnit/@ref)>1">
									<ul>
										<xsl:for-each select="listOfOrgUnit/habOrgUnit/refOrgUnit">
											<li><xsl:apply-templates select="key('objet',@ref)/orgUnitName"/></li>
										</xsl:for-each>
									</ul>
								</xsl:when>
								<xsl:otherwise>
									<xsl:value-of select="key('objet', listOfOrgUnit/habOrgUnit/refOrgUnit/@ref)/orgUnitName"/>
								</xsl:otherwise>
							</xsl:choose>
						</li>
					</ul>
				</xsl:when>
			</xsl:choose>
	</xsl:template>

	<!-- Descriptif de la donnée "Dénomination nationale" dans ROF -->
	<xsl:template match="licProNatName">
		<h3><xsl:call-template name="tCommunGestionLibelle"><xsl:with-param name="pIdent" select="'libLicencePro'"/></xsl:call-template></h3>
		<p><xsl:call-template name="tCommunGestionLibelle"><xsl:with-param name="pIdent" select="'libDenomNationale'"/></xsl:call-template><xsl:value-of select="Name"/></p>
		<p><xsl:call-template name="tCommunGestionLibelle"><xsl:with-param name="pIdent" select="'libSecteurProf'"/></xsl:call-template><xsl:value-of select="sectAct"/></p>
	</xsl:template>
	
	<!-- Descriptif de la donnée "Description générale du contexte [publication]" dans ROF -->
	<xsl:template match="contexteEtEnjeux">
		<xsl:apply-templates select="contexteEtEnjeuxInfo"/>
		<p><xsl:call-template name="tCommunGestionLibelle"><xsl:with-param name="pIdent" select="'libSchema'"/></xsl:call-template><xsl:apply-templates select="webLink"/></p>
	</xsl:template>
	<xsl:template name="tDateTimeTransformDate">
		<xsl:param name="date"/>
		<xsl:value-of select="substring($date,9,2)"/>
		<xsl:text>-</xsl:text>
		<xsl:value-of select="substring($date,6,2)"/>
		<xsl:text>-</xsl:text>
		<xsl:value-of select="substring($date,1,4)"/>
	</xsl:template>
	<xsl:template match="habiliCreatDate">
		<p><xsl:call-template name="tCommunGestionLibelle"><xsl:with-param name="pIdent" select="'libCreatDate'"/></xsl:call-template>
		<xsl:apply-templates select="@date"/></p>
	</xsl:template>
	<xsl:template match="habiliValidDuration">
		<p><xsl:call-template name="tCommunGestionLibelle"><xsl:with-param name="pIdent" select="'libDuration'"/></xsl:call-template>
		<xsl:apply-templates select="text()"/> ans</p>
	</xsl:template>
	<xsl:template match="dateCA|dateCEVU|dateCS">
		<p><xsl:value-of select="header"/> : <xsl:apply-templates select="@date"/></p>
	</xsl:template>
	<xsl:template match="habiliCreatDate/@date | dateCA/@date| dateCS/@date| dateCEVU/@date">
		<xsl:call-template name="tDateTimeTransformDate">
			<xsl:with-param name="date" select="."/>
		</xsl:call-template>
	</xsl:template>
	<!-- Politique des stage de l'établissement, partenariants académiques ou professionnels -->
	<xsl:template match="partnership">
		<!--<h3><xsl:call-template name="tCommunGestionLibelle"><xsl:with-param name="pIdent" select="'libPartenariat'"/></xsl:call-template></h3>
		<ul>
			<li><xsl:call-template name="tCommunGestionLibelle"><xsl:with-param name="pIdent" select="'libDenomPrincipale'"/></xsl:call-template><xsl:value-of select="partnerName/text[@lang=$_lang]"/></li>
			<li><xsl:apply-templates select="partnershipInfo/infoBlock"/></li>
			<li><xsl:call-template name="tCommunGestionLibelle"><xsl:with-param name="pIdent" select="'libCodeRNE'"/></xsl:call-template><xsl:value-of select="refOrgUnit/@ref"/></li>
			
			<li><xsl:call-template name="tCommunGestionLibelle"><xsl:with-param name="pIdent" select="'libPolitiqueStage'"/></xsl:call-template><xsl:apply-templates select="training/trainingStrategy"/></li>
		</ul>-->
	
		<div>
			<xsl:if test="not(infoBlock/header)"><h3><xsl:call-template name="tCommunGestionLibelle"><xsl:with-param name="pIdent" select="'libPartenariat'"/></xsl:call-template></h3></xsl:if>
			<xsl:apply-templates select="*[name()!='refOrgUnit']"/>
			<xsl:if test="refOrgUnit/@ref">
				<ul>
					<xsl:apply-templates select="refOrgUnit"/>
				</ul>
			</xsl:if>
		</div>
	</xsl:template>

	<!-- Descriptif de la donnée "" dans ROF -->
	<xsl:template match="equivalence">
		<h3><xsl:call-template name="tCommunGestionLibelle"><xsl:with-param name="pIdent" select="'libEquivalence'"/></xsl:call-template></h3>
	</xsl:template>

	<!-- Descriptif de la donnée "Modalités d'organisation des études à l'étranger" dans ROF -->
	<xsl:template match="i13nProg">
		<h3><xsl:call-template name="tCommunGestionLibelle"><xsl:with-param name="pIdent" select="'libOrganisationEtudeEtranger'"/></xsl:call-template></h3>
		<ul>
			<li><xsl:call-template name="tCommunGestionLibelle"><xsl:with-param name="pIdent" select="'libNomProgramme'"/></xsl:call-template><xsl:value-of select="i13ProgName/text[@language=$_lang or not(@language)]"/></li>
			<li><xsl:call-template name="tCommunGestionLibelle"><xsl:with-param name="pIdent" select="'libModaliteBiDiplomation'"/></xsl:call-template><xsl:value-of select="i13ProgPartner/partnershipInfo/diploma[@agreement='bidiplomation']/description/text[@language=$_lang or not(@language)]"/></li>
			<li><xsl:call-template name="tCommunGestionLibelle"><xsl:with-param name="pIdent" select="'libInformation'"/></xsl:call-template><xsl:apply-templates select="i13ProgInfo"/></li>
		</ul>
	</xsl:template>
	
	<!-- Descriptif de la donnée "Lien avec d'autres certifications" dans ROF -->
	<xsl:template match="relatedPrograms">
		<xsl:apply-templates select="relationInfo"/>
		<xsl:if test="refProgram/@ref">
			<ul>
				<xsl:apply-templates select="refprogram"/>
			</ul>
		</xsl:if>
	</xsl:template>

</xsl:stylesheet>