<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0"
	xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
	exclude-result-prefixes="xsl xhtml"
	xmlns="http://www.w3.org/1999/xhtml"
	xmlns:xhtml="http://www.w3.org/1999/xhtml">
	<xsl:output method="xml" indent="yes"
		doctype-system="http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd"
		doctype-public="-//W3C//DTD XHTML 1.0 Strict//EN"
		media-type="text/html" encoding="UTF-8"
		omit-xml-declaration="yes" xml:lang="fr" xml:space="preserve" />
	<xsl:param name="_lang">fr-FR</xsl:param>
	<xsl:param name="baseActionURL" />
	<xsl:param name="absActionURL" />
	<xsl:param name="_pas">10</xsl:param>
	<xsl:param name="debug">0</xsl:param>
	<xsl:param name="_oid" />
	<xsl:param name="_oidSpecialite" />
	<xsl:param name="_profil">profilv3</xsl:param>
	<xsl:param name="_recherche">0</xsl:param>
	<xsl:param name="baseMediaURL">media/</xsl:param>
	<!-- recuperation des param pour les valeurs des formulaires -->
	<xsl:param name="domaine" />
	<xsl:param name="diplome" />
	<xsl:param name="title" />
	<xsl:param name="intitule" />
	<xsl:param name="basket" select="0" />

	<!-- Trouver le Fichier des constantes -->
	<xsl:variable name="variablesExt"
		select="document('../commun/variablesExt.xml')" />
	<xsl:variable name="langueCDM" select="/CDM/@language" />
	<!-- FICHIERS INCLUDE UTILISEES   -->
	<xsl:include href="commun_fr-FR.xsl" />
	<xsl:include href="commun/xhtml.xsl" />
	<xsl:template match="/">
		<xsl:call-template name="html" />
	</xsl:template>
	<xsl:template name="user-titreFenetre">
		Catalogue des formations de l'université X
	</xsl:template>
	<xsl:template name="user-navigation">
		<div id="navigation">
			<ul>
				<li><a href="{$absActionURL}/{$_lang}/accueil">Accueil</a></li>
				<li class="actif">Feuilleter</li>
				<li>
					<a href="{$absActionURL}/{$_lang}/recherche">Recherche</a>
				</li>
			</ul>
		</div>
	</xsl:template>
	<xsl:template name="user-titre">
		Recherche par navigation
	</xsl:template>
	<xsl:template name="user-ariane">Vous êtes : Recherche</xsl:template>

	<xsl:template name="user-col_gauche">
		<xsl:if test="count(/CDM/program[programCode/@codeSet='erasmus'])=0">
			<p>La recherche n'a fourni aucun résultat!</p>
		</xsl:if>
		<xsl:apply-templates select="/CDM/properties/infoBlock/extension/uniform/constantes/domaineDiplome[@type='domaine']/data" />
	</xsl:template>
    <xsl:template match="contactData">
		<p>Adresse : <xsl:value-of select="adr/extadr"/><xsl:text>, </xsl:text><xsl:value-of select="adr/street"/><xsl:text>, </xsl:text><xsl:value-of select="adr/pcode"/><xsl:text> </xsl:text><xsl:value-of select="adr/locality"/><xsl:text>, </xsl:text><xsl:value-of select="adr/country"/></p>
		<p>Tel : <xsl:value-of select="telephone"/></p>
		<p>Fax : <xsl:value-of select="fax"/></p>
		<p><a href="mailto:{email}"><xsl:value-of select="email"/></a></p>
		<hr/>
	</xsl:template>
	<xsl:template name="user-col_droite">
		<h3><xsl:value-of select="/CDM/orgUnit[1]/orgUnitName/text[@language=$_lang]"/></h3>
		<xsl:apply-templates select="/CDM/orgUnit[1]/contacts/contactData"/>
		<h3>En savoir plus</h3>
		<p><a href="{/CDM/orgUnit[1]/webLink/href}"><xsl:value-of select="/CDM/orgUnit[1]/webLink/linkName"/></a></p>
	</xsl:template>
	<xsl:template match="program">
		<li><a href="{$absActionURL}/{$_lang}/fiche/description/{@id}"><xsl:value-of select="programName/text[@language=$_lang]"/></a></li>
	</xsl:template>
	<xsl:template match="domaineDiplome/data">
		<xsl:variable name="domaine" select="@import"/>
		<xsl:if test="/CDM/program[infoBlock/subBlock[@userDefined='HABILITATION']/subBlock[@userDefined='DOMAINE']/subBlock/@userDefined=$domaine]">
			<h2><xsl:value-of select="value"/></h2>
			<ul>
				<xsl:apply-templates select="/CDM/program[infoBlock/subBlock[@userDefined='HABILITATION']/subBlock[@userDefined='DOMAINE']/subBlock/@userDefined=$domaine]"/>
			</ul>
		</xsl:if>
	</xsl:template>
</xsl:stylesheet>