<?xml version="1.0" encoding="ISO-8859-1"?>

<xsl:stylesheet version="1.0"
	xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
	exclude-result-prefixes="xsl xhtml"
	xmlns="http://www.w3.org/1999/xhtml"
	xmlns:xhtml="http://www.w3.org/1999/xhtml">

	<!-- Cles d'acces au CDM-fr -->
	<xsl:key name="objet" match="orgUnit | program | subProgram | course | person" use="@id"/>
	<xsl:key name="noeud" match="noeud" use="@nid"/>
	<xsl:key name="noeudId" match="noeud" use="@id"/>
	<xsl:key name="noeudType" match="noeud" use="@typeObjet"/>
	<xsl:key name="noeudNiveau" match="noeud" use="@niveau"/>
	
	<!-- Liste des parametres dans l'URL -->
	<xsl:param name="_lang" />
	<xsl:param name="baseActionURL" />
	<xsl:param name="absActionURL" />
	<xsl:param name="_pas">10</xsl:param>
	<xsl:param name="debug">0</xsl:param>
	<xsl:param name="_oid" />
	<xsl:param name="_oidSpecialite" />
	<xsl:param name="_oidUe" />
	<xsl:param name="_onglet" />
	<xsl:param name="_profil">amue</xsl:param>
	<xsl:param name="_recherche">0</xsl:param>
	<xsl:param name="baseMediaURL">media/</xsl:param>
	<!-- recuperation des param pour les valeurs des formulaires -->
	<xsl:param name="domaine" />
	<xsl:param name="diplome" />
	<xsl:param name="ufr" />
	<xsl:param name="title" />
	<xsl:param name="intitule" />
	<xsl:param name="basket" select="0" />

	
	<!-- Fichier des libelles et constantes -->
	<xsl:variable name="variablesExt"
	select="document('../../variablesExt.xml')" />

	<xsl:variable name="idP">
		<xsl:choose>
			<xsl:when test="$_oidSpecialite!=''">
				<xsl:value-of select="key('noeud',$_oidSpecialite)/@id"/>
			</xsl:when>
			<xsl:otherwise>
				<xsl:value-of select="$_oid"/>
			</xsl:otherwise>
		</xsl:choose>
	</xsl:variable>
	<xsl:variable name="nidP">
		<xsl:choose>
			<xsl:when test="$_oidSpecialite!=''">
				<xsl:value-of select="$_oidSpecialite"/>
			</xsl:when>
			<xsl:otherwise>
				<xsl:value-of select="/CDM/properties/infoBlock/extension/hierarchy/noeud/@nid"/>
			</xsl:otherwise>
		</xsl:choose>
	</xsl:variable>
	<xsl:variable name="degree"/>
	<xsl:variable name="langueCDM" select="/CDM/@language" />
	<xsl:variable name="ongletEnCours" select="normalize-space($_onglet)"/>
	
	
	<!-- FICHIERS INCLUDE UTILISEES en commun -->
	
	<xsl:include href="sectionCNU.cdmfr.xsl" />
	<xsl:include href="contactData.cdmfr.xsl" />
	<xsl:include href="level.cdmfr.xsl" />
	<xsl:include href="learningObjectives.cdmfr.xsl" />
	<xsl:include href="admissionInfo.cdmfr.xsl" />
	<xsl:include href="recommendedPrerequisites.cdmfr.xsl" />
	<xsl:include href="formalPrerequisites.cdmfr.xsl" />
	<xsl:include href="formOfTeaching.cdmfr.xsl" />
	<xsl:include href="formOfAssessment.cdmfr.xsl" />
	<xsl:include href="expenses.cdmfr.xsl" />
	<xsl:include href="credits.cdmfr.xsl" />
	<xsl:include href="natureElements.cdmfr.xsl" />
	

	<xsl:template name="user-titreCatalogue"><xsl:value-of select="$variablesExt/variables/pageTitle/header[@type='0']/value[@lang=$_lang]"/></xsl:template>
	<xsl:template name="user-recherche" >
		<form id="rechercheSimple" action="{$absActionURL}/{$_lang}/postRecherche" method="post">
			<span class="recherche">Recherche simple</span>
			<br/>
			<input type="hidden" name="_debut" value="0"/>
			<input type="hidden" name="__1" value="__intitule_pt_AND"/>
			 <!-- <label for="__intitule_pt_AND">Intitulé :</label> -->
			            <input class="entree" size="22" name="__intitule_pt_AND" type="text">
			              <xsl:attribute name="value"><xsl:choose><xsl:when test="$intitule!=''"><xsl:value-of select="$intitule"/></xsl:when><xsl:otherwise></xsl:otherwise></xsl:choose></xsl:attribute>
			            </input>
			            <!-- Envoyer la recherche : -->
			            <input type="submit" class="bouton"  value=""/>
		</form>
	</xsl:template>
	<xsl:template name="user-langue" >
		<xsl:choose><xsl:when test="$_lang='en-EN'"><a href="{$absActionURL}/fr-FR/accueil">Français</a></xsl:when><xsl:otherwise><a href="{$absActionURL}/en-EN/accueil">Anglais</a></xsl:otherwise></xsl:choose>
	</xsl:template>
	<xsl:template name="user-pied" >
		<hr/>
		<span class="gauche" >Uniform Version 4.0 pour ROF Octobre 2012</span><span class="droit" ><xsl:value-of select="/CDM/orgUnit[1]/orgUnitName/text[@language=$_lang]"/></span> 
		<hr/>
	</xsl:template>
	<xsl:template name="user-css">
		<link media="all" type="text/css" rel="stylesheet" href="media/css/main.css" />
	</xsl:template>
	<xsl:template name="user-scripts">
		<script type="text/javascript">
			function nleFenetre(url) 
            { 
            options = "location=yes, scrollbars=yes,resizable=yes,toolbar=yes,status=yes,menubar=yes,width=700,height=500" ; options += ",top=" + String(window.screen.Height/2 - 400) ;
            options += ",left=" + String(window.screen.Width/2 - 300) ; var wNleF = window.open(url,"wNleF",options);
            return false ; 
            }
        </script>
		<script language="JavaScript">
	<xsl:comment>
	<![CDATA[

	function show_hide(bloc,blocimg, baseMediaURL)
	{
		elt=document.getElementById(bloc);
		if (elt.style.display == 'none') {
			  document.getElementById(bloc).style.display='block';
			  document.getElementById(blocimg).src=baseMediaURL+'/images/plier.jpg';
		}
		else {
			  document.getElementById(bloc).style.display='none';
			  document.getElementById(blocimg).src=baseMediaURL+'/images/deplier.jpg';
		}
	}
	
	]]>
	</xsl:comment>
	</script>
	
	</xsl:template>
	<xsl:template name="user-stat" >	<!--inserer ici le tag utilise pour votre dispositif de statitiques web-->	</xsl:template>

	<xsl:template name="tUser-col_droite">
		<xsl:param name="pNom"/>
		<xsl:param name="pContactData"/>
		<xsl:param name="pLienLibelle"/>
		<xsl:param name="pLienURL"/>
		<xsl:if test="not($pNom ='')">
			<h3><xsl:value-of select="$pNom"/></h3>
		</xsl:if>
		<xsl:if test="not($pContactData ='')">
			<xsl:apply-templates select="/CDM/orgUnit[1]/contacts/contactData"/>
		</xsl:if>
	</xsl:template>
	
	<xsl:template name="tLienEnSavoirPlus">
		<xsl:param name="pLienURL"/>
		<xsl:if test="not(normalize-space($pLienURL) ='')">
			<a href="{$pLienURL}"><xsl:value-of select="$pLienURL"/></a>
		</xsl:if>
	</xsl:template>
	
	<!-- en provenance de fiche.xml -->
	<xsl:template match="searchword[position()=1]">
		<xsl:value-of select="text()"/>
	</xsl:template>
	<xsl:template match="searchword[position()&gt;1]"><xsl:text>, </xsl:text><xsl:value-of select="text()"/>
	</xsl:template>
	<xsl:template match="lov[@info='erasmus']">
		<li>[<xsl:value-of select="@code"/>] <xsl:value-of select="text()"/></li>
	</xsl:template>
	<xsl:template match="lov[@info='rome']">
		<li>[<xsl:value-of select="@code"/>] <xsl:value-of select="text()"/></li>
	</xsl:template>
	
	<!-- Templates utilisées par plusieurs objets -->

	<xsl:template name="tCommunGestionLibelle">
		<xsl:param name="pIdent"/>
		<xsl:value-of select="$variablesExt/variables/libelleVar/libellePart[@type=normalize-space($pIdent)]/value[@lang=$_lang]"/>
	</xsl:template>
	
	<!-- File d'ariane  -->
	<xsl:template name="ariane">
		<xsl:choose><xsl:when test="$idP=$_oid"><xsl:value-of select="key('objet', $_oid)/programName/text[@language=$_lang]"/></xsl:when><xsl:otherwise><a href="{$absActionURL}/{$_lang}/fiche/description/{$_oid}"><xsl:value-of select="key('objet', $_oid)/programName/text[@language=$_lang]"/></a> > <xsl:value-of select="substring-after(key('objet', $idP)/programName/text[@language=$_lang],' ')"/></xsl:otherwise></xsl:choose>
	</xsl:template>
	
	<!-- Ajout CLV : Fil d'ariane complet -->
	<xsl:template name="ariane2">
		<div class="ariane2"><xsl:apply-templates select="/CDM/properties/infoBlock/extension/hierarchy/noeud" mode="ariane2"/></div>
	</xsl:template>
	<xsl:template match="noeud" mode="ariane2">
		> <xsl:call-template name="construireLien"><xsl:with-param name="noeud" select="."/></xsl:call-template>
		<xsl:if test="@nid!=$nidP"><xsl:apply-templates select="noeud[descendant-or-self::noeud/@nid=$nidP][1]" mode="ariane2"/></xsl:if>
	</xsl:template>
	
	<!-- Modif CLV : Affichage de l'arborescence de la formation -->
	<xsl:template name="construireLien">
		<xsl:param name="noeud"/>
		<xsl:param name="objet"/>
		<xsl:variable name="ecran">fiche</xsl:variable>
		<xsl:variable name="onglet">description</xsl:variable>
		
		<xsl:choose>
			<xsl:when test="$nidP!=$noeud/@nid">
				<xsl:choose>
					<xsl:when test="$noeud/@typeObjet!='course'">
						<!-- cas général : Parcours, année, semestres -->
						<a href="{$absActionURL}/{$_lang}/{$ecran}/{$onglet}/{$_oid}/{$noeud/@nid}">
							<xsl:value-of select="$noeud/@libelle"/>
						</a>
					</xsl:when>
					<xsl:otherwise>
						<a href="{$absActionURL}/{$_lang}/{$ecran}/programme/{$_oid}/{$noeud/@nid}#ficheEC">
							<xsl:value-of select="$noeud/@libelle"/>
						</a>
					</xsl:otherwise>
				</xsl:choose>
			</xsl:when>
			<xsl:otherwise>
				<xsl:value-of select="$noeud/@libelle"/>
			</xsl:otherwise>
		</xsl:choose>
	</xsl:template>
	
	<xsl:template name="listeElementsDossier">
		<ul type="none">
			<xsl:apply-templates select="/CDM/properties/infoBlock/extension/hierarchy/noeud" mode="listeElementsDossier"/>
		</ul>
	</xsl:template>

	<xsl:template match="noeud" mode="listeElementsDossier">
		<!-- Cas ou tout est deplié -->
		<xsl:choose>
			<xsl:when test="$_oidUe = 'deplier'">
				<li>
					<xsl:call-template name="construireLien"><xsl:with-param name="noeud" select="."/></xsl:call-template>
					<xsl:if test="noeud">
						<ul>
							<xsl:apply-templates select="noeud" mode="listeElementsDossier"/>
						</ul>	
					</xsl:if>
				</li>
			</xsl:when>
			<xsl:when test="$_oidUe = 'replier'">
				<li style="list-style-type:none">
					<xsl:if test="noeud[position()!=last()]">
						<a href="javascript:void(0);" onclick="show_hide('bloc_{@nid}','img_{@nid}', '{$baseMediaURL}');">
							<img id="img_{@nid}" src="{$baseMediaURL}/images/deplier.jpg" border="0" />
						</a>
					</xsl:if>
					<xsl:call-template name="construireLien"><xsl:with-param name="noeud" select="."/></xsl:call-template>
					<xsl:if test="noeud">
						<ul>
							<xsl:choose>
								<xsl:when test="noeud[position() &gt; 1]">
									<div id="bloc_{@nid}" style="display:none" class="pliage">
										<xsl:apply-templates select="noeud" mode="listeElementsDossier"/>
									</div>
								</xsl:when>
								<xsl:otherwise>
									<div id="bloc_{@nid}" class="pliage">
										<xsl:apply-templates select="noeud" mode="listeElementsDossier"/>
									</div>
								</xsl:otherwise>
							</xsl:choose>
						</ul>
					</xsl:if>
				</li>
			</xsl:when>
			<xsl:otherwise>
				<li style="list-style-type:none">
					<xsl:choose>
						<!-- 1er cas : on est dans l'arborescence : affichage des noeuds parents -->
						<xsl:when test="noeud[descendant-or-self::noeud/@nid=$nidP][1]">
							<xsl:if test="noeud[position()!=last()]">
								<a href="javascript:void(0);" onclick="show_hide('bloc_{@nid}','img_{@nid}', '{$baseMediaURL}');">
									<img id="img_{@nid}" src="{$baseMediaURL}/images/plier.jpg" border="0" />
								</a>
							</xsl:if>
							<xsl:call-template name="construireLien"><xsl:with-param name="noeud" select="."/></xsl:call-template>
								<ul>
									<div id="bloc_{@nid}" class="pliage"><xsl:apply-templates select="noeud" mode="listeElementsDossier"/>
									</div>
								</ul>
						</xsl:when>
						<!-- Sinon, on est au niveau de la mention -->
						<xsl:otherwise>
							<xsl:if test="noeud[position()!=last()]">
								<a href="javascript:void(0);" onclick="show_hide('bloc_{@nid}','img_{@nid}', '{$baseMediaURL}');">
									<img id="img_{@nid}" src="{$baseMediaURL}/images/deplier.jpg" border="0" />
								</a>
							</xsl:if>
							<xsl:call-template name="construireLien"><xsl:with-param name="noeud" select="."/></xsl:call-template>
							<xsl:if test="noeud">
								<ul>
									<xsl:choose>
										<xsl:when test="noeud[position() &gt; 1]">
											<div id="bloc_{@nid}" style="display:none" class="pliage">
												<xsl:apply-templates select="noeud" mode="listeElementsDossier"/>
											</div>
										</xsl:when>
										<xsl:otherwise>
											<div id="bloc_{@nid}" class="pliage">
												<xsl:apply-templates select="noeud" mode="listeElementsDossier"/>
											</div>
										</xsl:otherwise>
									</xsl:choose>
								</ul>
							</xsl:if>
						</xsl:otherwise>
					</xsl:choose>
				</li>
			</xsl:otherwise>
		</xsl:choose>
	</xsl:template>
	<!--
	<xsl:template name="listeElementsDossier">
		<ul>
			<xsl:apply-templates select="/CDM/properties/infoBlock/extension/hierarchy/noeud" mode="listeElementsDossier"/>
		</ul>
	</xsl:template>

	<xsl:template match="noeud" mode="listeElementsDossier">
		<li>
			<xsl:call-template name="construireLien"><xsl:with-param name="noeud" select="."/></xsl:call-template>
			<xsl:if test="noeud">
				<ul>
					<xsl:apply-templates select="noeud" mode="listeElementsDossier"/>
				</ul>	
			</xsl:if>
		</li>
	</xsl:template>-->
	
	<!-- Fin affichage de l'arborescence -->
</xsl:stylesheet>